Agreement among duplicate records

Christy, You can use the magic of SQL!

/*
    %CheckDupes(dsn=, varname=, missingval= -1);

    dsn        = This is the name of the dataset to process
    varname    = This is the name of the variable to check for value agreement
    missingval = This is the default value to use for missing values in the results.  Default= -1;
*/

%macro CheckDupes(dsn=, varname=, missingval=-1);

/*-- Magic and Wizardry is below this line --*/
proc sql;
    create view matches_&varname
    as
    select RecordID, &varname, count(*) as cnt
    from &dsn
    group by RecordID, &varname;

    create table agreement_&varname
    as
    select 
        RecordID, 
        count(distinct case when missing(&varname) then &missingval else &varname end ) 
                label='Agreement of Variables - # Unique Values' as Agreement, 
        count(*) label='\\# of Records' as NumRecords, 
        min(case when missing(&varname) then &missingval else &varname end ) 
              label='minimum value observed' as minValue, 
        max(case when missing(&varname) then &missingval else &varname end ) 
              label='maxmimum value observed' as maxValue,
        case when calculated Agreement = 1 then 'MATCH' else 'NO_MATCH' end 
              label='Match Status' as MatchStat
    from matches_&varname
    group by RecordID;
quit;

title "Match Status for Variable: &varname";
proc freq data=agreement_&varname;
tables MatchStat /missing;
run;

%mend;

To run the duplicates check for a variable just execute the macro:

%CheckDupes(dsn=yourDataSet, varname=Gender);

The default value for Missing is -1 you can change that by adding it as a parameter;

%CheckDupes(dsn=yourDataSet, varname=Gender, missingval=9999999999);

If you're processing a character variable, you'll need to change the missing value as such:

%CheckDupes(dsn=yourDataSet, varname=Gender, missingval='Missing');

You can also do it using a standard DATA step and BY processing:

proc sort data=test;
    by RecordID Gender;
run;

data test_agreement (keep=RecordID GenderAgreement Count);
    set test;
    by RecordID;
    retain GenderAgreement;
    retain Count;
    retain _PastGender;
    _PastGender = lag(Gender);
    if first.RecordID then do;
        GenderAgreement = 1;        
        Count = 1;
    end;
    else do;
        Count = Count + 1;
        if _PastGender ne Gender then do;
            GenderAgreement = 0;
        end;        
    end;
    if last.RecordID then do;
        output;
    end;
run;

proc sql;

create table output as

select RecordID,

case

when count(distinct Gender) = 1 then '1-yes'

when count(distinct Gender) > 1 then '0-no'

else ' ' end as Gender_agreement ,

count(*) as Count

from datasetname

group RecordID;

quit;